在單片機(jī)開發(fā)過程中.一些非線性的控制過程.最適合做一個(gè)表格來(lái).時(shí)時(shí)改變系統(tǒng)的參數(shù).達(dá)到控制的目的.最常的如產(chǎn)生正弦的的程.就是建一個(gè)大的數(shù)組時(shí)時(shí)改變輸出的8位字節(jié)送給外部DA.由DA生成一個(gè)完整的正弦波.當(dāng)然了.LED顯示也是一個(gè)例子.通過建一個(gè)數(shù)組來(lái)實(shí)現(xiàn)段碼的點(diǎn)亮點(diǎn)滅.下面就是一個(gè)LED表---digits[0]
#define SEG_a 0x01
#define SEG_b 0x02
#define SEG_c 0x04
#define SEG_d 0x08
#define SEG_e 0x10
#define SEG_f 0x20
#define SEG_g 0x40
#define SEG_dot 0x80
unsigned char digits[10] = {
(SEG_a|SEG_b|SEG_c|SEG_d|SEG_e|SEG_f), // 0
(SEG_b|SEG_c), // 1
(SEG_a|SEG_b|SEG_d|SEG_e|SEG_g), // 2
(SEG_a|SEG_b|SEG_c|SEG_d|SEG_g), // 3
(SEG_b|SEG_c|SEG_c|SEG_f|SEG_g), // 4
(SEG_a|SEG_c|SEG_d|SEG_f|SEG_g), // 5
(SEG_a|SEG_c|SEG_d|SEG_e|SEG_f|SEG_g), // 6
(SEG_a|SEG_b|SEG_c), // 7
(SEG_a|SEG_b|SEG_c|SEG_d|SEG_e|SEG_f|SEG_g), // 8
(SEG_a|SEG_b|SEG_c|SEG_d|SEG_f|SEG_g) // 9
};
C查表就太簡(jiǎn)單了temp2 = digits[ show_data[i] ];一句搞定,C中還有一個(gè)switch語(yǔ)句也是一個(gè)很好的用查表語(yǔ)句
C51匯編就相對(duì)麻煩一點(diǎn).不過MCS-51指令系統(tǒng)中有專用的查表指令：MOVC A,@A+DPTR和MOV A,@A+PC.
segtab:
dw 000ch
dw 000ah
dw 000ch ;0
dw 000ch
dw 0000h
dw 0000h ;1
dw 0008h
dw 000eh
dw 0004h ;2
......................
希望看了此文之后.大家對(duì)查表的一個(gè)清楚認(rèn)識(shí)
MOVC A,@A+DPTR指令，DPTR作為基址寄存器時(shí)，其值為16位而且可根據(jù)需要設(shè)計(jì)，故可用于在64KROM范圍內(nèi)查表。編寫查表程序時(shí)，首先把表的首址送入DPTR中，再將要查找的數(shù)據(jù)序號(hào)（或下表值）送入A中，然后就可以使用該指令進(jìn)行查表操作，并將結(jié)果送累加器A中。
MOVC A,@A+PC指令，PC作為基址寄存器時(shí)，其值由指令的位置確定，它只能設(shè)在查表指令操作碼下的256個(gè)字節(jié)范圍內(nèi)。編寫查表程序時(shí)，首先把查表數(shù)據(jù)的序號(hào)送入A中，再把從查表指令到表的首地址間的偏移量與A值相加，然后使用該指令進(jìn)行查表操作，并把結(jié)果送累加器A中。
下面是把內(nèi)部RAM 30H-37H單元中的十六進(jìn)制數(shù)依次轉(zhuǎn)換為ASCII碼，并存入內(nèi)部RAM 60H-6FH單元之中。用查表法編寫程序。
分析：由于十六進(jìn)制數(shù)是從0～F，對(duì)應(yīng)的ASCII碼為30H～46H，每一個(gè)單元存放的16進(jìn)制數(shù)，轉(zhuǎn)換為ASCII碼后分別存入2個(gè)單元，低位存低地址，高位存高地址。用ANL A ，#0FH 分別取高4位和低4位。 進(jìn)行查表轉(zhuǎn)換成相應(yīng)的ASCII碼。
MOVC A , @A+DPTR 程序如下：
ORG 0000H
AJMP MAININITIAL
ORG 0050H
MAININITIAL: ;給30H-37H賦初值
MOV R0,#30H ;設(shè)置存數(shù)指針R0初值
MOV R1,#00H ;設(shè)置賦值變量個(gè)數(shù)計(jì)數(shù)寄存器R1(循環(huán)計(jì)數(shù)器)初值
MOV DPTR,#initialtab
NEXTINITIAL:
MOV A,R1
MOVC A,@A+DPTR ;查表數(shù)據(jù)送累加器A
MOV @R0,A
INC R0 ;指針增一
INC R1 ;循環(huán)計(jì)數(shù)器增一
CJNE R1,#8,NEXTINITIAL ;判給30H-3FH賦初值完否
MAIN:
MOV R0,#30H ;設(shè)置十六進(jìn)制數(shù)地址指針
MOV R1,#60H ;設(shè)置ASCII碼地址指針
MOV R7,#08H ;需拼裝的十六進(jìn)制數(shù)字節(jié)個(gè)數(shù)
MOV DPTR,#ACSIITAB
ABC:
MOV A,@R0 ;取十六進(jìn)制數(shù)
MOV B,A ;暫存
ANL A,#0F0H ;取十六進(jìn)制數(shù)的字節(jié)高4位
RR A ;取十六進(jìn)制數(shù)的字節(jié)高4位移到字節(jié)的低4位
RR A
RR A
RR A
MOVC A,@A+DPTR ;查表數(shù)據(jù)送累加器A
MOV @R1,A ;保存轉(zhuǎn)換結(jié)果
INC R1 ;轉(zhuǎn)換結(jié)果指針增一
MOV A,B
ANL A,#0FH ;取十六進(jìn)制數(shù)的字節(jié)低4位
MOVC A,@A+DPTR ;查表數(shù)據(jù)送累加器A
MOV @R1,A ;保存轉(zhuǎn)換結(jié)果
INC R1 ;轉(zhuǎn)換結(jié)果指針增一
INC R0 ;轉(zhuǎn)換數(shù)據(jù)指針增一
DJNZ R7,ABC ;繼續(xù)
SJMP $
initialtab: ;給30H-37H賦值用初值表
DB 23H,6DH,09H,7FH,8CH,1EH,4BH,5AH
ACSIITAB: ;0～F，對(duì)應(yīng)的ASCII碼表
DB "012345678"
DB "9ABCDEF"
END
MOVC A,@A+PC程序如下：
ORG 0000H
AJMP MAININITIAL
ORG 0050H
MAININITIAL: ;給30H-37H賦初值
MOV R0,#30H ;設(shè)置存數(shù)指針R0初值
MOV R1,#00H ;設(shè)置賦值變量個(gè)數(shù)計(jì)數(shù)寄存器R1(循環(huán)計(jì)數(shù)器)初值
MOV DPTR,#initialtab
NEXTINITIAL:
MOV A,R1
MOVC A,@A+DPTR ;查表數(shù)據(jù)送累加器A
MOV @R0,A
INC R0 ;指針增一
INC R1 ;循環(huán)計(jì)數(shù)器增一
CJNE R1,#8,NEXTINITIAL ;判給30H-3FH賦初值完否
MAIN:
MOV R0,#30H ;設(shè)置十六進(jìn)制數(shù)地址指針
MOV R1,#60H ;設(shè)置ASCII碼地址指針
MOV R7,#08H ;需拼裝的十六進(jìn)制數(shù)字節(jié)個(gè)數(shù)
MOV DPTR,#ACSIITAB
ABC:
MOV A,@R0 ;取十六進(jìn)制數(shù)
MOV B,A ;暫存
ANL A,#0F0H ;取十六進(jìn)制數(shù)的字節(jié)高4位
RR A ;取十六進(jìn)制數(shù)的字節(jié)高4位移到字節(jié)的低4位
RR A
RR A
RR A
ACALL TRANACSAII ;查表數(shù)據(jù)送累加器A
MOV @R1,A ;保存轉(zhuǎn)換結(jié)果
INC R1 ;轉(zhuǎn)換結(jié)果指針增一
MOV A,B
ANL A,#0FH ;取十六進(jìn)制數(shù)的字節(jié)低4位
ACALL TRANACSAII ;查表數(shù)據(jù)送累加器A
MOV @R1,A ;保存轉(zhuǎn)換結(jié)果
INC R1 ;轉(zhuǎn)換結(jié)果指針增一
INC R0 ;轉(zhuǎn)換數(shù)據(jù)指針增一
DJNZ R7,ABC ;繼續(xù)
SJMP $
initialtab: ;給30H-37H賦值用初值表
DB 23H,6DH,09H,7FH,8CH,1EH,4BH,5AH
TRANACSAII:
INC A ;查表之前A加1是因?yàn)镸OVC指令與數(shù)據(jù)表之間有一個(gè)地址單元的間隔(RET指令)
MOVC A,@A+PC ;由于數(shù)據(jù)表緊跟MOVC指令之后,因此以PC作為基址寄存器比較方便.
RET
ACSIITAB: ;0～F，對(duì)應(yīng)的ASCII碼表
DB "012345678"
DB "9ABCDEF"
end
其它單片機(jī)跟C51查表類似.下面介紹松翰的單片機(jī)的查表程序.松翰單片機(jī)查表是通過X.Y寄存器來(lái)達(dá)到指向的表的目的如下
b0mov z,#segtab$L
b0mov y,#segtab$M
b0mov a,freqh ;led 3
add z,a
b0bts0 fc
incms y;表加1
nop
movc
下載文檔
