電路：

采用AT89S52單片機(jī)。

P3.0到P3.3外接四個按鍵。
P3.4到P3.7是控制四個數(shù)碼管的位選端口，P1口是數(shù)碼管的段選端口。

要求：

初始數(shù)字都是0。
每按一次第一個按鍵第一個數(shù)字 + 1；
每按一次第二個按鍵第二個數(shù)字 + 2；
每按一次第三個按鍵第三個數(shù)字 + 3；
每按一次第四個按鍵第四個數(shù)字 + 4。

;===================================================
最佳答案：

按照要求，用PROTEUS繪制電路，并仿真，效果截圖如下：

控制程序用匯編語言編寫，下列程序，已經(jīng)調(diào)試成功：

ORG 0000H
JMP START

START:
MOV 30H, #0
MOV 31H, #0
MOV 32H, #0
MOV 33H, #0
;----------------------------
M_LOOP:
CALL DISP
MOV P3, #0FH
MOV A, P3 ;讀入按鍵信息.
CPL A
ANL A, #0FH
JZ M_LOOP ;沒有按鍵就循環(huán)顯示.
;--------------------
CALL DISP ;延時消抖.
MOV P3, #0FH
MOV A, P3
CPL A
ANL A, #0FH
JZ M_LOOP ;再次確認(rèn).
MOV B, #1
JB ACC.0, J1 ;分支.
JB ACC.1, J2
JB ACC.2, J3
JB ACC.3, J4
JMP M_LOOP
;------------------下面計算加1234
J4: INC B
J3: INC B
J2: INC B
J1: MOV A, #2FH
ADD A, B
MOV R0, A
MOV A, @R0
ADD A, B
MOV B, #8
DIV AB
MOV @R0, B
;------------------下面等待按鍵釋放.
J_J:
CALL DISP
MOV P3, #0FH
MOV A, P3
ORL A, #0F0H
CPL A
JNZ J_J
JMP M_LOOP
;------------------下面是顯示程序
DISP:
MOV R0, #30H
MOV R2, #10H
D_LOOP:
MOV A, @R0
INC R0
ADD A, #(D_TAB - $ - 3)
MOVC A, @A + PC
MOV P3, #0FH
MOV P1, A
MOV P3, R2
CALL DELAY
MOV A, R2
RL A
MOV R2, A
CJNE R2, #1, D_LOOP
RET
;----------------------------
D_TAB:
DB 0C0H, 0F9H, 0A4H, 0B0H, 99H, 92H, 82H, 0F8H
DB 80H, 90H, 88H, 83H, 0C6H, 0A1H, 86H, 8EH, 0FFH ;FF是空白的代碼.
;---------------------------------------
DELAY:
MOV R6, #20
D1: MOV R7, #250
DJNZ R7, $
DJNZ R6, D1
RET
;---------------------------------------
END

;===================================================

后記：
提問者的電路已經(jīng)做成了 PCB 板子，顯示部分的實際電路是采用了三極管反相器來進(jìn)行位驅(qū)動。
因此，顯示程序應(yīng)該做如下修改：

;------------------下面是顯示程序
DISP:
MOV R0, #30H
; MOV R2, #10H
MOV R2, #0EFH
D_LOOP:
MOV A, @R0
INC R0
ADD A, #(D_TAB - $ - 3)
MOVC A, @A + PC
; MOV P3, #0FH
MOV P3, #255
MOV P1, A
MOV P3, R2
CALL DELAY
MOV A, R2
RL A
MOV R2, A
; CJNE R2, #1, D_LOOP
CJNE R2, #254, D_LOOP
RET
;----------------------------

把修改后的程序通過電子郵件進(jìn)行傳遞，稍候即有郵件回復(fù)：
太牛了 我弄了好幾天了 。。沒弄好。。謝謝 行啦。一次就燒錄成功了！非常感謝。。
程序工作在實際的電路板上的照片如下：